Algoritma Sorting plus Implementasinya

Sorting atau istilahnya untuk mengurutkan data, ada 2 bentuk terdiri dari Ascending dan Descending.

• Sorting secara ascending adalah cara mengurutkan data mulai data bernilai terkecil sampai terbesar. 
• Sedangkan descending mengurutkan data mulai dari data terbesar sampai terkecil.

Sebagai contoh misalkan diberikan data berupa bilangan berikut ini:

3 9 1 4 0 2

 Hasil sorting ascending adalah 0 1 2 3 4 9, dan hasil secara descending adalah 9 4 3 2 1 0.

Ascending
mengurutkan data secara ascending.


Untuk memudahkan pemrosesan data, lebih enak kalau kita nyatakan terlebih dahulu data bilangan di atas ke dalam bentuk notasi xi dengan i = 1, 2, …, 6. 
Sehingga dalam hal ini x1=3, x2=9, x3=1, x4=4, x5=0 dan x6=2.

Jika kita akan mengurutkan data secara ascending, maka harapan kita urutan data pertama adalah data yang memiliki nilai paling kecil. Karena itu kita harus mencari data terkecil dari semua data yang ada, lalu tempatkan ia ke data urutan pertama. 
Bagaimana dengan data urutan pertama sebelumnya? Bukankah nantinya dia akan tertimpa dengan data terkecil itu? Tidak… data urutan pertama sebelumnya akan kita tukar tempatnya dengan milik data terkecil. Misalkan data terkecil terletak pada urutan ke-4 dari seluruh data, maka data pertama kita tempatkan ke urutan ke-4 dan data terkecil diletakkan ke urutan pertama.

-->

Pseudocode dalam Pascal untuk mencari nilai terkecil dari semua data (x1, x2, …, x6) sekaligus mencari tempatnya.

min := x[1];
for i:=1 to 6 do
begin
    if (x[i] <= min) then
    begin
       min := x[i];
       tempatnya_min := i;
    end;
end;

Jadi pertama-tama, kita anggap nilai minimum adalah x1. Lalu nilai minimum ini kita bandingkan dengan semua data yang ada. Jika ditemukan nilai xi yang lebih kecil atau sama dengan nilai minimum, maka xi itulah nilai minimum yang baru, sekaligus tempat miliknya data minimum ini (i) kita catat. Nah setelah nilai minimum dari semua data ditemukan, maka selanjutnya kita tukar tempat nilai minimum tadi dengan tempat data pertama.

temp := x[1];
x[1] := x[tempatnya_min];
x[tempatnya_min] := temp;

Sehingga pseudocode proses mencari nilai terkecil dan menukar tempatnya dengan data pertama menjadi

min := x[1];
for i:=1 to 6 do
begin
    if (x[i] <= min) then
    begin
       min := x[i];
       tempatnya_min := i;
    end;
end;

temp := x[1];
x[1] := x[tempatnya_min];
x[tempatnya_min] := temp;

Nah setelah ditukar tempat antara data pertama dengan data terkecil maka urutan data menjadi

0 9 1 4 3 2

Proses selanjutnya, kita ulangi lagi proses yang sama yaitu mencari data terkecil dari kelompok data urutan ke-2 sampai dengan ke-6. Lalu tukar tempat data terkecil tersebut dengan tempat data urutan ke-2. Berikut ini pseudocodenya

min := x[2];
for i:=2 to 6 do
begin
    if (x[i] <= min) then
    begin
       min := x[i];
       tempatnya_min := i;
    end;
end;

temp := x[2];
x[2] := x[tempatnya_min];
x[tempatnya_min] := temp;

Tukar tempat antara data minimum dengan data ke-2 menghasilkan urutan data

0 1 9 4 3 2

Proses yang sama kembali dilakukan untuk kelompok data mulai urutan ke-3 sampai ke-6. Cari nilai minimumnya, lalu tukar tempat dengan data ke-3. Begitu seterusnya sampai dengan kelompok data ke-6 sampai ke-6. Berikut ini hasil urutan data untuk setiap proses

hasil urutan untuk kelompok data x3 s/d x6 : 0 1 2 4 3 9
hasil urutan untuk kelompok data x4 s/d x6 : 0 1 2 3 4 9
hasil urutan untuk kelompok data x5 s/d x6 : 0 1 2 3 4 9
hasil urutan untuk kelompok data x6 s/d x6 : 0 1 2 3 4 9

Nah… setelah proses selesai diperolehlah data yang terurut secara ascending. Pada contoh ini sebenarnya proses sorting ascending selesai pada kelompok data x4 s/d x6. Namun untuk keperluan generalisasi (bisa diterapkan ke semua kasus) maka kita selesaikan proses sampai dengan kelompok data terakhir.

Dengan demikian secara umum, untuk data x1 … xn, berikut ini pseudocode untuk sorting secara ascending

for kelompok := 1 to n do
begin
   min := x[kelompok];
   for i := kelompok to n do
   begin
      if (x[i] <= min) then
      begin
         min := x[i];
         tempatnya_min := i;
      end;
   end;

   temp := x[kelompok];
   x[kelompok] := x[tempatnya_min];
   x[tempatnya_min] := temp;
end;

Sedangkan berikut ini contoh implementasi algoritma sorting ascending di atas pada kasus yang diberikan di atas.

program sorting;
var x : array[1..100] of integer;
    i, n, min, kelompok, temp, tempatnya_min : integer;
begin
    { membuat data array yang terdiri dari data : 3 9 1 4 0 2 }
    x[1] := 3;
    x[2] := 9;
    x[3] := 1;
    x[4] := 4;
    x[5] := 0;
    x[6] := 2;
    n := 6; {jumlah data}
    { proses sorting ascending }
    for kelompok := 1 to n do
    begin
       min := x[kelompok];
       for i := kelompok to n do
       begin
          if (x[i] <= min) then
          begin
             min := x[i];
             tempatnya_min := i;
          end;
       end;
       temp := x[kelompok];
       x[kelompok] := x[tempatnya_min];
       x[tempatnya_min] := temp;
    end;
    { menampilkan hasil sorting }
    for i:=1 to n do
    begin
       writeln(x[i], ' ');
    end;
end.

Bagaimana dengan sorting descending? ,berarti kita tidak lagi mencari data minimum, tapi data maksimum. Bagaimana caranya? ya… tinggal ubah saja tanda <= menjadi >=. Oya, jangan lupa ubah pula nama variabel min menjadi max.

via : blog rosihani dot net

Share this

Wooly boobly